AviSynth function: ShowTitleSafe

[dokidoki]

I wrote this function a while back and thought maybe someone else might find it useful. It draws a rectangle on the footage showing where the title safe area is.

It's meant to be used (temporarily) on your final output to see if anything might be cut off when shown on some displays. For example, text on some videos at Anime North 2006 was cut off when the videos were played. I know the title tool in Premiere shows the title safe box for you, but you might have overlays that you've done in another program.

Code: Select all

function ShowTitleSafe(clip v1)
{
  v = BlankClip(v1,width=2,height=Height(v1)/10*8,color=$ffffff)
  h = BlankClip(v1,width=Width(v1)/10*8,height=2,color=$ffffff)
  v1.Overlay(v,x=Width(v1)/10,y=Height(v1)/10,mode="difference").\
     Overlay(v,x=Width(v1)/10*9,y=Height(v1)/10,mode="difference").\
     Overlay(h,x=Width(v1)/10,y=Height(v1)/10,mode="difference").\
     Overlay(h,x=Width(v1)/10,y=Height(v1)/10*9,mode="difference")
}

I'm defining the border as 10%, which is what Premiere's titler seems to do. It's not an exact science since displays vary. For instance, the BBC suggests 6.7% x 5.0% for 4:3 SD.

[Willen]

I generally use 10% as my guideline. I've tested all the TVs in my house and they do vary, but the best was about 6%, the worst was a bit over 10% in width 7% in height (yes, it stretches the picture horizontally, but its an old set).

[Qyot27]

This'll be useful. What values would need to be changed to enable using the BBC's title safe recommendations or action safe boundaries? I tried fiddling with it to see if I could do so and just ended up with the lines being drawn in odd shapes, among other things, instead.

[dokidoki]

Here's a BBC title safe version. In the original function, I could have made the percentages configurable, but didn't bother.

Code: Select all

####################################################################################
function ShowTitleSafeBBC(clip v1)
{
  v = BlankClip(v1,width=2,height=Height(v1)*900/1000,color=$ffffff)
  h = BlankClip(v1,width=Width(v1)*866/1000,height=2,color=$ffffff)
  v1.Overlay(v,x=Width(v1)*67/1000,y=Height(v1)*50/1000,mode="difference").\
     Overlay(v,x=(Width(v1)*933/1000)-2,y=Height(v1)*50/1000,mode="difference").\
     Overlay(h,x=Width(v1)*67/1000,y=Height(v1)*50/1000,mode="difference").\
     Overlay(h,x=Width(v1)*67/1000,y=(Height(v1)*950/1000)-2,mode="difference")
}